VB.NET – inviare un’email attraverso il Namespace System.Net.Mail con gestione degli errori

29ott/083

VB.NET – inviare un’email attraverso il Namespace System.Net.Mail con gestione degli errori

A partire dalla versione 2.0 di .NET il Namespace System.Web.Mail è stato rimpiaziato da System.Net.Mail, dedicato interamente all'invio di email e molto più completo ed esteso rispetto al precedente. In questo stralcio di codice mostro come implementare una semplice funzione che consente l'invio di email in formato HTML, con un allegato e in modalità asincrona, così da poter intercettare facilmente eventuali errori. Il codice è ampiamente commentato, in caso di dubbi o problemi non esitate a postare un commento.

Imports System.Net.Mail 'importo il Namespace
Dim mail As MailMessage 'questa dichiarazione deve essere globale
 
'funzione per l'invio di un messaggio email
Private Sub invia_messaggio()
            Try
                mail = New MailMessage()
 
                'definisco i dati del mittente
                Dim mittente As New MailAddress("mittente@boh.it", _
                                                "Nome Mittente")
                mail.From = mittente
 
                'aggiungo un destinatario, copiando questa
                'riga si possono aggiungere destinatari multipli
                mail.To.Add("destinatario@boh.it")
 
                'se si desidera richiedere una notifica di lettura
                'del messaggio decommentare la seguente
                'riga di codice
                'mail.Headers.Add("Disposition-Notification-To", _
                '                 "<mittente@boh.it>")
 
                'definisco l'oggetto del messaggio
                mail.Subject = "Oggetto messaggio"
 
                'definisco la priorità del messaggio
                mail.Priority = Net.Mail.MailPriority.High
 
                'definisco la codifica del corpo del messaggio
                mail.BodyEncoding = System.Text.Encoding.UTF8
                'definisco il messaggio in modalità HTML
                mail.IsBodyHtml = True
                'definisco il corpo del messaggio
                mail.Body = "<html><head></head><body>CIAO</body></html>"
 
                'aggiungo un allegato specificandone il percorso esattto
                mail.Attachments.Add(New Attachment("C:\ciao.txt"))
 
                'definisco l'indirizzo del server SMTP
                Dim smtp As New SmtpClient("smtp.boh.it")
                'definisco i dati per l'autenticazione al server SMTP
                smtp.UseDefaultCredentials = False
                smtp.Credentials = New NetworkCredential("nome utente", _
                                                         "password")
 
                'al termine dell'invio verra richiamata 
                'la funzione invio_completato
                AddHandler smtp.SendCompleted, AddressOf invio_completato
 
                Dim Token As New Object
                'invio il messaggio in modalità asincrona
                smtp.SendAsync(mail, Token)
            Catch ex As SmtpException
                'qui il codice da eseguire in caso di mancanza 
                'di una connessione ad internet
                MsgBox("Nessuna connessione ad internet attiva", _
                        MsgBoxStyle.Exclamation, _
                        "Errore")
                mail.To.Clear()
                mail.Attachments.Clear()
                mail.Dispose()
            End Try
        End Sub
 
'la seguente funzione viene richiamata in ogni caso 
'al termine dell'invio del messaggio
Private Sub invio_completato(ByVal sender As Object, _
                ByVal e As System.ComponentModel.AsyncCompletedEventArgs)
            Dim Token As Object = e.UserState
 
            If e.Cancelled Then
                'l'invio è stato annullato
                Debug.WriteLine("Invio annullato")
            End If
 
            If e.Error IsNot Nothing Then
                'si è verificato un'errore durante l'invio
                Debug.WriteLine("Errore: " & e.Error.ToString)
 
            Else
                'invio completato senza errori
                Debug.WriteLine("Invio completato")
            End If
 
            mail.To.Clear()
            mail.Attachments.Clear()
            mail.Dispose()
        End Sub

Mi piace!

Iscriviti al nostro feed RSS!

Tag: .NET, allegati, allegato, attachment, attachments, e-mail, email, HTML, invio asincrono, mail, MailMessage, SendAsync, smtp, System.Net.Mail, VB .NET, visual basisc .net Lascia un commento

Commenti (3) Trackback (0) iscriviti ai commenti di questo post

Mirco
agosto 15th, 2010 - 04:25

Grazie è proprio quello che stavo cercando!!!!

( RISPONDI )
Daniele
agosto 29th, 2010 - 02:50

Grazie, esempio chiarissimo e utilissimo, mi serviva proprio!!

E’ possibile ricevere in ritorno un messaggio di conferma che la mail è stata letta?

Grazie Mille!!
ciao

( RISPONDI )
- BG
  settembre 3rd, 2010 - 00:34
  
  Ciao Daniele, ho modificato l’esempio di codice inserendo la possibilità di richiedere l’invio della notifica di lettura del messaggio. Ciao
  
  ( RISPONDI )